SAS—基于熵的連續(xù)變量的離散化

今天介紹下整個(gè)程序邏輯及sas代碼的詳細(xì)介紹。

首先宏 %BinContVard調(diào)用了宏%CandSplits；然后宏%CandSplits又調(diào)用宏

%BestSplit、%GValue；最后通過(guò)宏%ApplyMap應(yīng)用于數(shù)據(jù)集。

下表是%BinContVar的參數(shù)

%BinContVar(Dsin,IVVar,DVVar,MMax,Acc,DsVarMap)

參數(shù)

描述

DSin

輸入數(shù)據(jù)集

IVVar

連續(xù)自變量

DVVar

二元因變量

MMax

設(shè)定的分組數(shù)量

Acc

最小分段的百分比規(guī)模

DsVarMap

包含映射規(guī)則的輸出數(shù)據(jù)集

首先，將初始數(shù)據(jù)集等距分為10段，然后把這些段數(shù)看作名義變量，基于熵方差利用最優(yōu)二元分類(lèi)法找出最優(yōu)分群。

宏%bincontvar的主要是作用是連續(xù)變量的最優(yōu)分段，嵌套了%CandSplits,這個(gè)宏的作用是對(duì)分段后的數(shù)據(jù)集在進(jìn)行分群，并選出最優(yōu)分群；宏%CandSplits嵌套了%BestSplits和%GValue兩個(gè)宏：宏%BestSplits是找出最優(yōu)分群，宏%GValue計(jì)算熵方差。

/*連續(xù)變量的最優(yōu)分段*/

/*

1.找出連續(xù)變量的最大最小值；

2.對(duì)連續(xù)變量進(jìn)行等距分段，并把這些段數(shù)看成名義變量；

3.對(duì)2所分段數(shù)進(jìn)行最優(yōu)分群，直到所設(shè)置的分群數(shù)

*/

%macro BinContVar(DSin, IVVar, DVVar, MMax, Acc, DSVarMap);

%local VarMax VarMin;

proc sql noprint;

select min(&IVVar), max(&IVVar) into :VarMin, :VarMax from &DSin;

quit;

%local Mbins i MinBinSize;

%let Mbins=%sysfunc(int(%sysevalf(1.0/&Acc)));/*設(shè)置等距分段數(shù)*/

%let MinBinSize=%sysevalf((&VarMax-&VarMin)/&Mbins);/*每段的長(zhǎng)度*/

/*定義每段后每段的最大最小值*/

%do i=1 %to %eval(&Mbins);

%local Lower_&i Upper_&i;

%let Upper_&i = %sysevalf(&VarMin + &i * &MinBinSize);

%let Lower_&i = %sysevalf(&VarMin + (&i-1)*&MinBinSize);

%end;

%let Lower_1 = %sysevalf(&VarMin-0.0001);

%let Upper_&Mbins=%sysevalf(&VarMax+0.0001);

/*對(duì)連續(xù)變量 income 進(jìn)行等距分段*/

data Temp_DS;

set &DSin;

%do i=1 %to %eval(&Mbins-1);

if &IVVar>=&&Lower_&i and &IVVar < &&Upper_&i Then Bin=&i;

%end;

if &IVVar>=&&Lower_&Mbins and &IVVar <= &&Upper_&MBins Then Bin=&MBins;

run;

/*計(jì)算出等距分段的每段最值*/

data temp_blimits;

%do i=1 %to %Eval(&Mbins-1);

Bin_LowerLimit=&&Lower_&i;

Bin_UpperLimit=&&Upper_&i;

Bin=&i;

output;

%end;

Bin_LowerLimit=&&Lower_&Mbins;

Bin_UpperLimit=&&Upper_&Mbins;

Bin=&Mbins;

output;

run;

proc sort data=temp_blimits;

by Bin;

run;

/*找出每段分段對(duì)應(yīng)的二元自變量每個(gè)類(lèi)別的頻數(shù)*/

proc freq data=Temp_DS noprint;

table Bin*&DVvar /out=Temp_cross;

table Bin /out=Temp_binTot;

run;

proc sort data=temp_cross;

by Bin;

run;

proc sort data= temp_BinTot;

by Bin;

run;

data temp_cont;

merge Temp_cross(rename=count=Ni2 )temp_BinTot(rename=Count=total) temp_BLimits ;/*Ni2:每個(gè)分段下對(duì)應(yīng)類(lèi)別的頻數(shù) total：每個(gè)分段下的總頻數(shù)*/

by Bin;

Ni1=total-Ni2;

PDV1=bin;

label Ni2= total=;

if Ni1=0 then output;

else if &DVVar=1 then output;

drop percent &DVVar;

run;

data temp_contold;

set temp_cont;

run;

/*合并所有含有ni1、ni2 、total= 0 的分段*/

proc sql noprint;

%local mx;

%do i=1 %to &Mbins;

select count(*) into : mx from Temp_cont where Bin=&i;

%if (&mx>0) %then %do;

select Ni1, Ni2, total, bin_lowerlimit, bin_upperlimit into

:Ni1,:Ni2,:total, :bin_lower, :bin_upper

from temp_cont where Bin=&i;

%if (&i=&Mbins) %then %do;

select max(bin) into :i1 from temp_cont where Bin<&Mbins;

%end;

%else %do;

select min(bin) into :i1 from temp_cont where Bin>&i;

%end;

%if (&Ni1=0) or (&Ni2=0) or (&total=0) %then %do;

update temp_cont set

Ni1=Ni1+&Ni1 ,

Ni2=Ni2+&Ni2 ,

total=total+&Total

where bin=&i1;

%if (&i<&Mbins) %then %do;

update temp_cont set Bin_lowerlimit = &Bin_lower where bin=&i1;

%end;

%else %do;

update temp_cont set Bin_upperlimit = &Bin_upper where bin=&i1;

%end;

delete from temp_cont where bin=&i;

%end;

%end;

%end;

quit;

proc sort data=temp_cont;

by pdv1;

run;

%local m;

/*將所有類(lèi)別定義為宏變量m*/

data temp_cont;

set temp_cont;

i=_N_;

Var=bin;

Bin=1;

call symput("m", compress(_N_));

run;

%local Nbins ;

%let Nbins=1;

%DO %WHILE (&Nbins <&MMax);

/*從所有候選分群中根據(jù)熵選擇最優(yōu)分群*/

%CandSplits(temp_cont, Temp_Splits);

Data Temp_Cont;

set Temp_Splits;

run;

%let NBins=%eval(&NBins+1);

%end;

data temp_Map1 ;

set temp_cont(Rename=Var=OldBin);

drop Ni2 PDV1 Ni1 i ;

run;

proc sort data=temp_Map1;

by Bin OldBin ;

run;

data temp_Map2;

retain LL 0 UL 0 BinTotal 0;

set temp_Map1;

by Bin OldBin;

Bintotal=BinTotal+Total;

if first.bin then do;

LL=Bin_LowerLimit;

BinTotal=Total;

End;

if last.bin then do;

UL=Bin_UpperLimit;

output;

end;

drop Bin_lowerLimit Bin_upperLimit Bin OldBin total;

run;數(shù)據(jù)分析師培訓(xùn)

proc sort data=temp_map2;

by LL;

run;

data &DSVarMap;

set temp_map2;

Bin=_N_;

run;

%mend;