SAS在DATA步中調(diào)用PROC步

給大家介紹一種方法，可以在DATA步中調(diào)用PROC過程，這樣就可以在DATA步中對PROC產(chǎn)生的結(jié)果進行操作。

具體如何實現(xiàn)？

首先肯定不是直接在DATA步中寫PROC，有些人可能會說用CALL EXECUTE，其實不然。CALL EXECUTE是在DATA步運行之后才調(diào)用。

在這里給大家介紹RUN_MACRO這個函數(shù)，通過該函數(shù)就可實現(xiàn)在DATA步中調(diào)用PROC，或者是另一個DATA步。

顧名思義，該函數(shù)就是用來調(diào)用macro的，但它有它的獨特之處：不能在DATA步中使用該函數(shù)，只能在FCMP過程中使用（自定義函數(shù)中使用）。

因此要實現(xiàn)在DATA步中調(diào)用PROC，需要三個步驟：

1.定義一個MACRO，其內(nèi)容就是一個PROC過程；

2.通過FMCP創(chuàng)建自定義函數(shù)，調(diào)用上面定義的MACRO；

3.在DATA步中調(diào)用自定義函數(shù)，即間接調(diào)用PROC過程；

下面用一個例子來說明：

創(chuàng)建宏（該宏是利用PROC SQL創(chuàng)建一個數(shù)據(jù)集，包含一個變量的非重復(fù)值）

%macro distinct_values;

%let input_table = %sysfunc(dequote(&input_table));

%let column = %sysfunc(dequote(&column));

%let output_table = %sysfunc(dequote(&output_table));

proc sql;

create table &output_table as

select distinct &column

from &input_table;

%mend;

創(chuàng)建自定義函數(shù)（在自定義函數(shù)中調(diào)用上面定義的宏）

proc fcmp outlib=work.funcs.sql;

function get_distinct_values(input_table $, column $, output_table $);

rc = run_macro('distinct_values', input_table, column, output_table);

return (rc);

endsub;

run;

在DATA步中調(diào)用

options cmplib = work.funcs;

data _null_;

rc = get_distinct_values('sashelp.shoes', 'region', 'work.regions');

id=open('work.regions');

if id then nobs=attrn(id,'NOBS');

put nobs;

run;

通過這種方式就可在DATA中調(diào)用PROC，從而使用PROC生成的結(jié)果。在上面的例子中，最后的DATA步調(diào)用PROC生成了數(shù)據(jù)集WORK.REGIONS，

然后通過OPEN函數(shù)打開該數(shù)據(jù)集，獲取到該數(shù)據(jù)集的觀測數(shù)。當(dāng)然你可以干其他的事情。

重點在于：RUN_MACRO調(diào)用宏后，會一直等待宏執(zhí)行完畢后才返回。因此緊接著get_distinct_values自定義函數(shù)后就可以使用宏產(chǎn)生的數(shù)據(jù)。

如果使用CALL EXECUTE調(diào)用宏，是在DATA步執(zhí)行完之后，才調(diào)用宏，實際上就是在DATA步之后增加了宏的調(diào)用。

注：雖然在第三步調(diào)用get_distinct_values之后就可以使用該數(shù)據(jù)，但不能使用SET WORK.REGIONS; 為什么呢？這是因為SET語句的運行機制決定的。

在程序編譯階段，如果有SET語句，就會將SET的數(shù)據(jù)集打開，但此時程序還未執(zhí)行，數(shù)據(jù)集根本沒有生成，因此就會報錯，提示數(shù)據(jù)集不存在。

所以要使用OPEN函數(shù)，來對該數(shù)據(jù)集進行操作。